CEK Machine

A CEK Machine is an abstract machine invented by Matthias Felleisen and Daniel P. Friedman that implements left-to-right call by value. It is generally implemented as an interpreter for functional programming languages, but can also be used to implement simple imperative programming languages. A state in a CEK machine includes a control statement, environment and continuation. The control statement is the term being evaluated at that moment, the environment is (usually) a map from variable names to values, and the continuation stores another state, or a special halt case. It is a simplified form of another abstract machine called the SECD machine. The CEK machine builds on the SECD machine by replacing the dump (call stack) with the more advanced continuation, and putting parameters directly into the environment, rather than pushing them on to the parameter stack first. Other modifications can be made which creates a whole family of related machines. For example, the CESK machine has the environment map variables to a pointer on the store, which is effectively a heap. This allows it to model mutable state better than the ordinary CEK machine. The CK machine has no environment, and can be used for simple calculi without variables.

Description

A CEK machine can be created for any programming language so the term is often used vaguely. For example, a CEK machine could be created to interpret the lambda calculus. Its environment maps variables to closures and the continuations are either a halt, a continuation to evaluate an argument (ar), or a continuation to evaluate an application after evaluating a function (ap):

Transition	From	To
Variable	x, E, K	t, E', K where closure(t,E') = E[x]
Application	(f e), E, K	f, E, ar(e, E, K)
Abstraction while evaluating function	Abs, E, ar(t, E', K)	t, E', ap(Abs, E, K)
Abstraction while evaluating argument	Abs, E, ap(λx.Exp, E', K)	Exp, E'[x=closure(Abs,E)], K

Representation of components

Each component of the CEK machine has various representations. The control string is usually a term being evaluated, or sometimes, a line number. For example, a CEK machine evaluating the lambda calculus would use a lambda expression as a control string. The environment is almost always a map from variables to values, or in the case of CESK machines, variables to addresses in the store. The representation of the continuation varies. It often contains another environment as well as a continuation type, for example argument or application. It is sometimes a call stack, where each frame is the rest of the state, i.e. a control statement and an environment.

Related machines

There are some other machines closely linked to the CEK machine.

CESK machine

The CESK machine is another machine closely related to the CEK machine. The environment in a CESK machine maps variables to pointers, on a "store" (heap) hence the name "CESK". It can be used to model mutable state, for example the Λ_σ calculus described in the original paper. This makes it much more useful for interpreting imperative programming languages, rather than functional ones.

CS machine

The CS machine contains just a control statement and a store. It is also described by the original paper. In an application, instead of putting variables into an environment it substitutes them with an address on the store and putting the value of the variable in that address. The continuation is not needed because it is lazily evaluated; it does not need to remember to evaluate an argument.

SECD machine

The SECD machine was the machine that CEK machine was based on. It has a stack, environment, control statement and dump. The dump is a call stack, and is used instead of a continuation. The stack is used for passing parameters to functions. The control statement was written in postfix notation, and the machine had its own "programming language". A lambda calculus statement like this:

(M N)

would be written like this:

N:M:ap

where ap is a function that applies two abstractions together.

Origins

On page 196 of "Control Operators, the SECD Machine, and the [math]\displaystyle{ \lambda }[/math]-Calculus", and on page 4 of the technical report with the same name, Matthias Felleisen and Daniel P. Friedman wrote "The [CEK] machine is derived from Reynolds' extended interpreter IV.", referring to John Reynolds's Interpreter III in "Definitional Interpreters for Higher-Order Programming Languages".

To wit, here is an implementation of the CEK machine in OCaml, representing lambda terms with de Bruijn indices:

type term = IND of int    (* de Bruijn index *)
          | ABS of term
          | APP of term * term

Values are closures, as invented by Peter Landin:

type value = CLO of term * value list

type cont = C2 of term * value list * cont
          | C1 of value * cont
          | C0

let rec continue (c : cont) (v : value) : value =
  match c, v with
    C2 (t1, e, k), v0 ->
     eval t1 e (C1 (v0, k))
  | C1 (v0, k), v1 ->
     apply v0 v1 k
  | C0, v ->
     v
and eval (t : term) (e : value list) (k : cont) : value =
  match t with
    IND n ->
     continue k (List.nth e n)
  | ABS t' ->
     continue k (CLO (t', e))
  | APP (t0, t1) ->
     eval t0 e (C2 (t1, e, k))
and apply (v0 : value) (v1 : value) (k : cont) =
  let (CLO (t, e)) = v0
  in eval t (v1 :: e) k

let main (t : term) : value =
  eval t [] C0

This implementation is in defunctionalized form, with cont and continue as the first-order representation of a continuation. Here is its refunctionalized counterpart:

let rec eval (t : term) (e : value list) (k : value -> 'a) : 'a =
  match t with
    IND n ->
     k (List.nth e n)
  | ABS t' ->
     k (CLO (t', e))
  | APP (t0, t1) ->
     eval t0 e (fun v0 ->
                  eval t1 e (fun v1 ->
                               apply v0 v1 k))
and apply (v0 : value) (v1 : value) (k : value -> 'a) : 'a =
  let (CLO (t, e)) = v0
  in eval t (v1 :: e) k

let main (t : term) : value =
  eval t [] (fun v -> v)

This implementation is in left-to-right continuation-passing style, where the domain of answers is polymorphic, i.e., is implemented with a type variable. This continuation-passing implementation is mapped back to direct style as follows:

let rec eval (t : term) (e : value list) : value =
  match t with
    IND n ->
     List.nth e n
  | ABS t' ->
     CLO (t', e)
  | APP (t0, t1) ->
     let v0 = eval t0 e
     and v1 = eval t1 e
     in apply v0 v1
and apply (v0 : value) (v1 : value) : value =
  let (CLO (t, e)) = v0
  in eval t (v1 :: e)

let main (t : term) : value =
  eval t []

This direct-style implementation is also in defunctionalized form, or more precisely in closure-converted form. Here is the result of closure-unconverting it:

type value = FUN of (value -> value)

let rec eval (t : term) (e : value list) : value =
  match t with
    IND n ->
     List.nth e n
  | ABS t' ->
     FUN (fun v -> eval t' (v :: e))
  | APP (t0, t1) ->
     let v0 = eval t0 e
     and v1 = eval t1 e
     in apply v0 v1
and apply (v0 : value) (v1 : value) : value =
  let (FUN f) = v0
  in f v1

let main (t : term) : value =
  eval t []

The resulting implementation is compositional. It is the usual Scott-Tarski definitional self-interpreter where the domain of values is reflexive (Scott) and where syntactic functions are defined as semantic functions and syntactic applications are defined as semantic applications (Tarski).

This derivation mimics Danvy's rational deconstruction of Landin's SECD machine. The converse derivation (closure conversion, CPS transformation, and defunctionalization) is documented in John Reynolds's article "Definitional Interpreters for Higher-Order Programming Languages", which is the origin of the CEK machine and was subsequently identified as a blueprint for transforming compositional evaluators into abstract machines as well as vice versa.

Modern times

The CEK machine, like the Krivine machine, does not only functionally correspond to a meta-circular evaluator (via a left-to-right call-by-value CPS transformation), it also syntactically corresponds to the [math]\displaystyle{ \lambda\widehat{\rho} }[/math] calculus -- a calculus that uses explicit substitution -- with a left-to-right applicative-order reduction strategy, and likewise for the SECD machine (via a right-to-left call-by-value CPS transformation).