Software:friendly interactive shell

fish

The friendly interactive shell
Original author(s)	Axel Liljencrantz
Developer(s)	ridiculousfish, siteshwar, JanKanis
Initial release	13 February 2005 (2005-02-13)
Stable release	3.1.2 / 29 April 2020 (2020-04-29)
Operating system	Unix-like
Type	Unix shell
License	GPL v2
Website	fishshell.com

The friendly interactive shell (fish) is a Unix shell that attempts to be more interactive and user-friendly than those with a longer history (i.e. most other Unix shells) or those formulated as function-compatible replacements for the aforementioned (e.g. zsh, the Falstad shell). The design goal of fish is to give the user a rich set of powerful features in a way that is easy to discover, remember, and use. fish is considered an "exotic shell", in that its syntax derives from neither the Bourne shell (ksh, Bash, zsh) nor the C shell (csh, tcsh). Also unlike previous shells, which disable certain features by default to save system resources, fish enables all features by default.

Highlights

fish has "search as you type" automatic suggestions based on history and current directory. This is essentially like Bash's history search, but because it is always on instead of being a separate mode, the user gets continuous feedback while writing the command line, and can select suggestions with the arrow keys, or as in Bash, press for a tab completion instead. Tab-completion is feature-rich, expanding file paths (with wildcards and brace expansion), variables, and many command specific completions. Command-specific completions, including options with descriptions, can to some extent be generated from the commands' manpages.

Fish has few syntactic rules, preferring features as commands rather than syntax. This makes features discoverable in terms of commands with options and help texts. Functions can also carry a human readable description. A special help command gives access to all the fish documentation in the user's web browser.

Syntax

The syntax resembles a POSIX compatible shell (such as Bash), but deviates in important ways where the creators believe the POSIX shell was badly designed.

# Variable assignment, set the variable 'foo' to the 
# value 'bar'.  Fish doesn't use the = operator, since 
# it is inherently whitespace sensitive.  Also, the set 
# command easily extends to work with arrays, scoping, etc.
> set foo bar
> echo $foo
bar
 
# Command substitution, assign the output of the command 
# 'pwd' into the variable 'wd'.  Fish doesn't use `` 
# since they can't be nested and look too much like ' '. 
# Don't use $() since $ is only used for variable 
# expansion in fish.
> set wd (pwd)
> echo $wd
~

# Array variables. 'A' becomes an array with 5 values:
> set A 3 5 7 9 12
# Array slicing. 'B' becomes the first two elements of 'A':
> set B $A[1 2]
> echo $B
3 5
# You can index with other arrays and even command 
# substitution output:
> echo $A[(seq 3)]
3 5 7
# Erase the third and fifth elements of 'A'
> set --erase A[$B]
> echo $A
3 5 9

# for-loop, convert jpegs to pngs
> for i in *.jpg
      convert $i (basename $i .jpg).png
  end
# Semicolons work like newlines:
> for i in *.jpg; convert $i (basename $i .jpg).png; end
# but the multi-line form is comfortable to use because 
# fish supports multi-line history and editing.

# while-loop, read lines /etc/passwd and output the fifth 
# colon-separated field from the file. This should be
# the user description.
> while read line
      set arr (echo $line|tr : \n)
      echo $arr[5]
  end < /etc/passwd

No implicit subshell

Some language constructs, like pipelines, functions and loops, have been implemented using so called subshells in other shell languages. Subshells are simply child programs that run a few commands for the shell and then exit. Unfortunately, this implementation detail typically has the side effect that any state changes made in the subshell, such as variable assignments, do not propagate to the main shell, which may surprise the user. Fish never forks off so-called subshells; all builtins are always fully functional.

# This will not work in many other shells, since the 'read' builtin
# will run in its own subshell. In Bash, the right side of the pipe
# can't have any side effects. In ksh, the below command works, but
# the left side can't have any side effects. In fish and zsh, both
# sides can have side effects.
> cat *.txt | read line

Variable assignment example

This Bash example does not do what it looks like: because the loop body is a subshell, the update to $found is not persistent.

found=''
cat /etc/fstab | while read dev mnt rest; do
  if test "$mnt" = "/"; then
    found="$dev"
  fi
done

Workaround:

found=''
while read dev mnt rest; do
  if test "$mnt" = "/"; then
    found="$dev"
  fi
done < /etc/fstab

Fish does not need a workaround:

set found ''
cat /etc/fstab | while read dev mnt rest
  if test "$mnt" = "/"
    set found $dev
  end
end

Helpful error messages

Error messages in fish are designed to actually tell the user what went wrong and what can be done about it.

> foo=bar
fish: Unknown command “foo=bar”. Did you mean “set VARIABLE VALUE”?
For information on setting variable values, see the help section on
the set command by typing “help set”.

> echo ${foo}bar
fish: Did you mean {$VARIABLE}? The '$' character begins a variable
name. A bracket, which directly followed a '$', is not allowed as a
part of a variable name, and variable names may not be zero characters
long. To learn more about variable expansion in fish, type “help
expand-variable”.

> echo $(pwd)
fish: Did you mean (COMMAND)? In fish, the '$' character is only used
for accessing variables. To learn more about command substitution in
fish, type “help expand-command-substitution”.

Universal variables

Fish has a feature known as universal variables, which allow a user to permanently assign a value to a variable across all the user's running fish shells. The variable value is remembered across logouts and reboots, and updates are immediately propagated to all running shells.

# This will make emacs the default text editor. The '--universal' (or '-U') tells fish to
# make this a universal variable.
> set --universal EDITOR emacs

# This command will make the current working directory part of the fish
# prompt turn blue on all running fish instances.
> set --universal fish_color_cwd blue

Other features

• Advanced tab completion.
• Syntax highlighting with extensive error checking.
• Support for the X clipboard.
• Smart terminal handling based on terminfo.
• Searchable command history.

Version 2 adds:

• Autosuggestions
• 256 terminal colors
• Web-based configuration
• Improved performance (by having more builtins).

Bash/fish translation table

Feature	Bash syntax	fish syntax	Comment
variable expansion: with word splitting and glob interpretation	$var or ${var[@]} or ${var[*]}	deliberately omitted	Identified as a primary cause of bugs in posix compatible shell languages
variable expansion: scalar	"$var"	deliberately omitted	Every variable is an array
variable expansion: array	"${var[@]}"	$var	Quoting not necessary to suppress word splitting and glob interpretation. Instead, quoting signifies serialization.
variable expansion: as a space separated string	"${var[*]}"	"$var"
history completion		implicit
history substitution	!!	deliberately omitted	Not discoverable
explicit subshell	(expression)	no equivalent
command substitution	"$(expression)"	(expression)
process substitution	<(expression)	(expression | psub)	Command, not syntax
logical operators	!cmd && echo FAIL || echo OK	not command and echo FAIL or echo OK
variable assignment	var=value	set var value
string processing: replace	"${HOME/alice/bob}"	string replace alice bob $HOME
string processing: remove prefix or suffix pattern, non-greedily or greedily	var=a.b.c "${var#*.}" #b.c "${var##*.}" #c "${var%.*}" #a.b "${var%%.*}" #a	string replace --regex '.*?\.(.*)' '$1' a.b.c #b.c string replace --regex '.*\.(.*)' '$1' a.b.c #c string replace --regex '(.*)\..*' '$1' a.b.c #a.b string replace --regex '(.*?)\..*' '$1' a.b.c #a
export variable	export var	set --export var	Options discoverable via tab completion
function-local variable	local var	by default
scope-local variable	no equivalent	set --local var
remove variable	unset var	set --erase var
check if a variable exists	test -v var	set --query var
array initialization	var=( a b c )	set var a b c	Every variable is an array
array iteration	for i in "${var[@]}"; do echo "$i" done	for i in $var echo $i end
argument vector: all arguments	"$@"	$argv
argument vector: indexing	"$1"	$argv[1]
argument vector: length	$#	(count $argv)
argument vector: shift	shift	set --erase argv[1]
array representation in environment variables	PATH="$PATH:$HOME/.local/bin"	set PATH $PATH $HOME/.local/bin	fish assumes colon as array delimiter for translating variables to and from the environment. This aligns with many array-like environment variables, like $PATH and $LS_COLORS.
export and run	LANG=C.UTF-8 python3	env LANG=C.UTF-8 python3	env LANG=C.UTF-8 python3 works in any shell, as env is a standalone program.
arithmetic	$((10/3))	math '10/3'	expr 10 / 3 works in any shell, as expr is a standalone program.
escape sequence	$'\e'	\e	printf '\e' works in both shells; their printf builtins are both compatible with the GNU printf standalone program.
single quoted string: escape sequences	'mom'\''s final backslash: \'	'mom\'s final backslash: \\'	Bash only requires replacement of the single quote itself in single quoted strings, but the replacement is 4 characters long. The same replacement works in fish, but fish supports a regular escape sequence for this, thus requires escaping backslashes too (except permits single backslashes that don't precede another backslash or single quote).

See also

• Comparison of command shells

External links

• – containing documentation and downloads
• fish on GitHub (active)
• fish on Gitorious (obsolete)
• fish on SourceForge (obsolete)
• Fish-users – general discussion list for fish users
• Shell Translation Dictionary - another Bash/Fish translation table